Mit Excel 365 hast du das Glück das es einige Funktionen bietet, die man in anderen Versionen händisch umsetzen müsste.

ralf_b hat bereits ein Paar genannt.

Folgender Code gehört in die Tabelle, in welcher sich die Tabelle befindet:

Es wird davon ausgegangen das die Tabelle in A1 beginnt.

Option Explicit

Public Sub Anwendungsbeispiel()
  
  Dim vntValues As Variant
  
  Call GetUniqueCarBrands(vntValues)
  ComboBox1.List = vntValues
  
  If ComboBox1.ListCount = 0 Then
    Exit Sub
  End If
  
  'ersten Eintrag vor-auswählen
  ComboBox1.ListIndex = 0
  
End Sub

Private Sub ComboBox1_Change()
  
  If ComboBox1.ListIndex < 0 Then Exit Sub
  
  Dim vntValues As Variant
  
  'Inhalt von ComboBox2 aktualisieren, wenn in ComboBox1 sich die Auswahl ändert
  Call GetUniqueCarModells(ComboBox1.Value, vntValues)
  ComboBox2.List = vntValues
  
  'ohne Auswahl
  ComboBox2.ListIndex = -1
  
End Sub

Public Function GetUniqueCarModells(CarBrand As String, Optional Values As Variant) As Long
  
  Dim rngTable As Excel.Range
  Set rngTable = GetTableRange()
  If rngTable Is Nothing Then
    GoTo NoValuesFound
  End If
  
  Dim vntResult As Variant
  vntResult = WorksheetFunction.Filter(rngTable, Me.Evaluate(rngTable.Columns(1).Address & "=""" & CarBrand & """"))
  If IsError(vntResult) Then
    GoTo NoValuesFound
  End If
  
  'zweite Spalte: "Modell"
  vntResult = WorksheetFunction.Index(vntResult, 0, 2)
  '2D-Array => 1D-Array
  vntResult = WorksheetFunction.Transpose(vntResult)
  'nur einzigartige Werte (doppelte werden herausgefiltert)
  vntResult = WorksheetFunction.Unique(vntResult, True)
  
  
  Values = vntResult
  GetUniqueCarModells = UBound(Values)
  
Exit Function
NoValuesFound:
  Values = Split(vbNullString)
  GetUniqueCarModells = 0
End Function

Public Function GetUniqueCarBrands(Optional Values As Variant) As Long
  
  Dim rngTable As Excel.Range
  Set rngTable = GetTableRange()
  If rngTable Is Nothing Then
    GoTo NoValuesFound
  End If
  
  Dim vntResult As Variant
  vntResult = WorksheetFunction.Unique(rngTable.Columns(1).Value)
  
  '2D-Array => 1D-Array
  vntResult = WorksheetFunction.Transpose(vntResult)
  
  
  Values = vntResult
  GetUniqueCarBrands = UBound(Values)
  
Exit Function
NoValuesFound:
  Values = Split(vbNullString)
  GetUniqueCarBrands = 0
End Function

Private Function GetTableRange() As Excel.Range
  Dim rngTable As Excel.Range
  Set rngTable = Range("A1").CurrentRegion
  If rngTable.Rows.Count > 1 Then
    Set GetTableRange = rngTable.Offset(1).Resize(rngTable.Rows.Count - 1)
  End If
End Function

Grüße