Thema Datum  Von Nutzer Rating
Antwort
12.11.2020 07:02:25 pixxel
NotSolved
Blau EMail an gefilterte Liste
 12.11.2020 10:28:55 volti
Solved
12.11.2020 11:39:49 Pixxel
Solved
12.11.2020 11:52:54 volti
NotSolved

Ansicht des Beitrags:
Von:
volti		 Datum:
12.11.2020 10:28:55		 Views:
496		 Rating:
     
Antwort:
 Nein
Thema:
EMail an gefilterte Liste

Hallo Pixxel,

hier ein Beispiel für die Generierung einer einfachen Mail. Die Sub kannst Du dann einem Button zuordnen...

Probiere es mal aus.

Sub SendeMail()
'Sub sendet eine Mail lt. Empfänger-Liste
 Dim sMailtext As String, sEmpfaenger As String
 Dim rZelle As Range
 
'Empfänger zusammensammeln
 With Sheets("Tabelle1")
   For Each rZelle In .Range("A2:A" & .Cells(Rows.Count, "A").End(xlUp).Row)
     If rZelle.EntireRow.Hidden = False Then
       If rZelle.Value Like "*@*.*" Then
          sEmpfaenger = sEmpfaenger & rZelle.Value & ";"
       End If
     End If
   Next rZelle
 End With
 If sEmpfaenger = "" Then Exit Sub      'Keine Empfänger angegeben => raus
 sEmpfaenger = Left$(sEmpfaenger, Len(sEmpfaenger) - 1)

 sMailtext = "Hallo, " & vbCrLf & vbCrLf _
           & "dies ist meine Mail" & vbCrLf
 
'Jetzt Mail erstellen
 With CreateObject("Outlook.Application").CreateItem(0)
  .Getinspector                         'Signatur holen
  .Subject = "Mein Betreff"             'Betreff
  .body = sMailtext & .body             'Bodytext incl. Signatur setzen
  .Importance = 1
  .To = sEmpfaenger                     'Empfänger
  .cc = ""                              'Kopieempfänger
  .Display                              'Mail anzeigen
 
 End With
End Sub

viele Grüße

Karl-Heinz

Ihre Antwort
  • Bitte beschreiben Sie Ihr Problem möglichst ausführlich. (Wichtige Info z.B.: Office Version, Betriebssystem, Wo genau kommen Sie nicht weiter)
  • Bitte helfen Sie ebenfalls wenn Ihnen geholfen werden konnte und markieren Sie Ihre Anfrage als erledigt (Klick auf Häckchen)
  • Bei Crossposting, entsprechende Links auf andere Forenbeiträge beifügen / nachtragen
  • Codeschnipsel am besten über den Code-Button im Text-Editor einfügen
  • Die Angabe der Emailadresse ist freiwillig und wird nur verwendet, um Sie bei Antworten auf Ihren Beitrag zu benachrichtigen
Thema: Name: Email:



  • Bitte beschreiben Sie Ihr Problem möglichst ausführlich. (Wichtige Info z.B.: Office Version, Betriebssystem, Wo genau kommen Sie nicht weiter)
  • Bitte helfen Sie ebenfalls wenn Ihnen geholfen werden konnte und markieren Sie Ihre Anfrage als erledigt (Klick auf Häckchen)
  • Bei Crossposting, entsprechende Links auf andere Forenbeiträge beifügen / nachtragen
  • Codeschnipsel am besten über den Code-Button im Text-Editor einfügen
  • Die Angabe der Emailadresse ist freiwillig und wird nur verwendet, um Sie bei Antworten auf Ihren Beitrag zu benachrichtigen

Thema Datum  Von Nutzer Rating
Antwort
12.11.2020 07:02:25 pixxel
NotSolved
Blau EMail an gefilterte Liste
 12.11.2020 10:28:55 volti
Solved
12.11.2020 11:39:49 Pixxel
Solved
12.11.2020 11:52:54 volti
NotSolved