Hallo,

falls Du das in Dein Mail aus dem anderen Thread einbauen möchtest, hier das Beispiel:

Sub Mail_Senden_mit_PDF()
'Sendet Mail mit integriertem Bereich als Bild mit Signatur
'Das Bild wird über das Kürzel ~ im Text platziert
 Dim WSh As Worksheet
 Dim sMailtext As String, sSignatur As String
 Dim sDateiName As String, T As String
    
'<<<Tabellenblatt anpassen>>>
 Set WSh = ThisWorkbook.Sheets("Tabelle1")  'Blatt mit Maildaten
  
 sDateiName = ThisWorkbook.FullName
 sDateiName = Left$(sDateiName, InStrRev(sDateiName, ".")) & "pdf"
 T = ThisWorkbook.Path & "\"
 sDateiName = Replace(sDateiName, T, T & WSh.Range("B4").Value & "_")
 
'<<<Tabellenblatt anpassen>>>
 ThisWorkbook.Sheets("Furnierte Platten").ExportAsFixedFormat Type:=xlTypePDF, _
     Filename:=sDateiName, Quality:=xlQualityStandard, _
     IncludeDocProperties:=True, _
     IgnorePrintAreas:=False, OpenAfterPublish:=False
    
 With CreateObject("Outlook.Application").CreateItem(0)
  .BodyFormat = 2                                   'HTML-Format, Angabe optional
  .Subject = "Bestellung " & WSh.Range("B4").Value  'Betreff
  .To = Replace(WSh.Range("E9").Value, vbLf, ";")   'Empfänger
   sMailtext = "<span style='font-family:Calibri;font-size:11pt;color:black;'>" _
             & "Guten Tag,<br><br>Im Anhang sende ich Ihnen die Bestellung für Auftrag " _
             & WSh.Range("B4").Value & ".<br>Gerne erwarte ich Ihre Bestätigung.<br></span>"
  .GetInspector:  sSignatur = .HTMLBody             'Signatur holen
  .HTMLBody = sMailtext & sSignatur
  .Display
 
'Anlage anfügen
  If Dir$(sDateiName) <> "" Then
     .Attachments.Add sDateiName                    'Anlage anfügen
  End If
    
 End With
   
End Sub

VG KH