Hallo Dennis,

für deinen Fall ist der Code hinter dem Link nicht ohne Anpassung direkt nutzbar.

Hier mal ein Beispiel, wie man es umsetzen könnte. Ich generiere hier ein paar Beispiele, die Empfänger müsstest du natürlich aus der Mail holen.

Option Explicit

Sub Test()
  
  Dim vntAllowedDomains As Variant 'Liste mit erlauben Domänen (WhiteList)
  Dim vntRecipients     As Variant 'Liste mit allen Empfängern
  
  Set vntAllowedDomains = New VBA.Collection
  Set vntRecipients = New VBA.Collection

'# erlaube Domänen (simpel) - Beispiel
  vntAllowedDomains.Add "@my-company.com"
  vntAllowedDomains.Add "@a-partnered-company.de"
'#

'# HINWEIS:
'#  True zu False ändern für Beispiel-Setup-2
#If True Then
' Beispiel-Setup-1 (fremde Domains vorhanden)
  
  vntRecipients.Add "max.mustermann@mircosoft.com"        '<- hier steigt er weiter unten direkt aus und fragt nach
  vntRecipients.Add "bla.blub@my-company.com"
  vntRecipients.Add "eva.mustermann@data.com"             '<- hier würde er als nächstes aussteigen
  vntRecipients.Add "uwe.hübner@a-partnered-company.de"
  vntRecipients.Add "inge.schubert@web.de"                '<- und hier ebenfalls

#Else
' Beispiel-Setup-2 (keine fremden Domains vorhanden)
  
  vntRecipients.Add "uwe.hübner@a-partnered-company.de"
  vntRecipients.Add "bla.blub@my-company.com"
  vntRecipients.Add "mein.name@my-company.com"
  
#End If


'#
'# Und los geht's #
'#

  Dim vntDomain         As Variant
  Dim vntRecipient      As Variant
  Dim blnForeignDomain  As Boolean 'Flag für: Domäne einer Fremdfirma liegt vor

  'alle Empfänger durchgehen
  For Each vntRecipient In vntRecipients
    
    'nachsehen ob die Domäne erlaubt ist
    '(simple Variante)
    blnForeignDomain = True
    For Each vntDomain In vntAllowedDomains
      If CBool(InStr(LCase$(vntRecipient), LCase$(vntDomain))) Then
        blnForeignDomain = False
        Exit For
      End If
    Next
    
    Debug.Print "'"; vntRecipient; "' => "; IIf(blnForeignDomain, "not_ok", "ok"); ""
    
    If blnForeignDomain Then
      Debug.Print " -> exit_for"
      Exit For
    End If
    
  Next
  
  If blnForeignDomain Then
    MsgBox "Sind sie sicher ~bla-blah, dass sie sicherlicher sicher sicher sind?", _
            vbQuestion + vbYesNo + vbDefaultButton2
  End If
  
End Sub

Grüße