Hallo,

dann mal noch vor X-mas, ist von der CPU her doch etwas harmloser als gedacht, damits automat. läuft, benötigst Du dazu noch eine EreignisProc in Deinem Tabellenblattmodul:

' **************************************************************
'  Modul:  Tabelle1  Typ: Klassenmodul des Tabellenblattes
' **************************************************************

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
With Target
    If .Address = "$D$4" Then _
       If .Value > 40 Then _
         Call Blinker(probjRange:=.Offset(1, 0)) _
       Else: Call Stop_Blinker
End With
End Sub

' **************************************************************
'  Modul:  Modul1  Typ: Standardmodul
' **************************************************************

Option Explicit

Private lblnRun As Boolean

Public Sub Blinker(ByRef probjRange As Range) '// © by Phelan....//
    Dim sng_t As Single
    Dim sngOn_Time As Single
    Dim sngOff_Time As Single
    Dim lngOn_Color As Long
    Dim lngOff_Color As Long
    Dim objBereich As Range
   
    sngOn_Time = 0.5
   
    sngOff_Time = 0.5
    lngOff_Color = xlColorIndexNone
   
    lblnRun = Not lblnRun
   
    Set objBereich = probjRange
    
    With objBereich.Interior
        lngOn_Color = .Color
        Do While lblnRun
            .Color = lngOn_Color
            sng_t = Timer: Do While Timer < sng_t + sngOn_Time: DoEvents: Loop
            .ColorIndex = lngOff_Color
            sng_t = Timer: Do While Timer < sng_t + sngOff_Time: DoEvents: Loop
        Loop
        .Color = lngOn_Color
    End With
    Set objBereich = Nothing
End Sub

Public Sub Stop_Blinker()
  lblnRun = False
End Sub

Gruß,