Hallo BibBen,

leider hat deine Lösung nicht funktioniert. In Office 2016 wirft das rng.Select einen Fehler wirft, da die zuvor gelöschte Shape zwar noch von rng referenziert wird, jedoch nicht mehr vorhanden ist.

Ich habe jetzt allerdings eine funktionierende Version:

Sub DeleteLastSelectedShape()
    Dim iShCnt As Integer
    Dim rng As ShapeRange
    
    Select Case Application.Version
        Case "16.0"
            Set rng = ActiveWindow.Selection.ShapeRange
            iShCnt = rng.Count
            If iShCnt > 0 Then
                Dim selIDs() As Integer
                ReDim selIDs(iShCnt)
                
                For ii = 1 To iShCnt
                    selIDs(ii) = ActiveWindow.Selection.ShapeRange(ii).Id
                Next ii
                
                'folgender Aufruf sorgt in Office 2016 dafür, dass nichts mehr ausgewählt wird
                ActiveWindow.Selection.ShapeRange(iShCnt).Delete 'zuletzt markiertes Element löschen
                
                'alle Elemente der Seite durchlaufen und prüfen, ob sie vorher ausgewählt waren
                'falls ja, wird das Element ausgewählt per .Select
                For ii = 1 To iShCnt - 1
                    For jj = 1 To ActiveSlide.Shapes.Range.Count
                        If ActiveSlide.Shapes.Range(jj).Id = selIDs(ii) Then
                            ActiveSlide.Shapes.Range(jj).Select (msoFalse)
                        End If
                    Next jj
                Next ii
                
            End If
        Case Else
            iShCnt = ActiveWindow.Selection.ShapeRange.Count
            If iShCnt > 0 Then
                ActiveWindow.Selection.ShapeRange(iShCnt).Delete
            End If
    End Select
End Sub


Function ActiveSlide() As Slide
'liefert eine Referenz auf die aktuelle Folie
'http://www.vbarchiv.net/tipps/tipp_993-aktive-folie-in-powerpoint-ermitteln.html

  On Error GoTo ErrHandler
  Set ActiveSlide = ActivePresentation.Slides( _
    ActiveWindow.View.Slide.Name)
  Exit Function
 
ErrHandler:
  Set ActiveSlide = Nothing
End Function

Ist zwar etwas komplizierter als erwartet, aber es funktioniert.

Danke für deine Hilfe

 Stephan