Hier nochmal komplett mit Durchschnitt - die Spalte kannst du anpassen:

Option Explicit

Private Declare Function URLDownloadToFile Lib "urlmon" _
  Alias "URLDownloadToFileA" ( _
  ByVal pCaller As Long, _
  ByVal szURL As String, _
  ByVal szFileName As String, _
  ByVal dwReserved As Long, _
  ByVal lpfnCB As Long) As Long
    
Public Sub download_und_import_bitcoin_kurse()
    If download_file <> 0 Then
        MsgBox "Problem beim herunterladen.", vbExclamation
        Exit Sub
    End If
      
    Call import
     
    MsgBox "Import erfolgreich.", vbInformation
End Sub

Public Sub durchschnitt()
    Dim i As Integer, j As Integer
    Dim summe As Double
    i = 2: j = 5    'Beginn E2
    
    For i = 2 To 22
        summe = summe + CDbl(Worksheets("Tabelle1").Cells(i, j))    'Evtl. Tabelle anpassen
    Next i
    
    MsgBox "Der Durchschnitt beträgt " & summe / 21, vbInformation
End Sub
  
Private Function download_file() As Long
    Dim strURL As String
    Dim strLocalFile As String
      
    'Link zum Donwload
    strURL = "http://www.quandl.com/api/v3/datasets/BITFINEX/BTCUSD.csv"
      
    'Pfad für den Speicherort
    strLocalFile = ThisWorkbook.Path & "\Bitcoin_" & Format(Date, "YYYYMMDD") & ".csv"
      
    'Datei herunterladen und Status zurückgeben
    download_file = URLDownloadToFile(0, strURL, strLocalFile, 0, 0)
End Function
  
Private Sub import()
    Dim fso As Object
    Dim txtStream As Object
    Dim i As Integer, j As Integer
    Dim strPfad As String
    Dim strDaten() As String
    Dim wksImport As Worksheet
    'Tabelle, in der importiert wird
    Set wksImport = Worksheets("Tabelle1")
    'Bereich in dem Eingefügt wird (1,1 = A1; 2,1 = A2..)
    i = 1: j = 1
    'Tabellenblatt leeren
    wksImport.Cells.Clear
      
    strPfad = ThisWorkbook.Path & "\Bitcoin_" & Format(Date, "YYYYMMDD") & ".csv"
    Set fso = CreateObject("Scripting.FilesystemObject")
    Set txtStream = fso.OpenTextfile(strPfad)
      
    Do While Not txtStream.AtEndOfStream
        strDaten() = Split(txtStream.ReadLine, ",")
        For j = 0 To UBound(strDaten())
            wksImport.Cells(i, j + 1) = strDaten(j)
        Next j
        i = i + 1
    Loop
      
    txtStream.Close
    
    Kill strPfad
    
    Set wksImport = Nothing
    Set txtStream = Nothing
    Set fso = Nothing
End Sub

Gruß

SJ