Moin! (v)

Versuch mal hier, Inhalte und das Bild (?) müssen nurnoch reingebracht werden.

Array spalte steht für die größe der Spalten von links nach rechts. Gruss!

 Sub Tabellenerstellung()
    Dim temp As Integer
    Dim spalte(1 To 8) As Double
    Dim rng As Range
    
    'Die Spaltenbreite festlegen
    spalte(1) = 1
    spalte(2) = 2.3
    spalte(3) = 1
    spalte(4) = 2.3
    spalte(5) = 1
    spalte(6) = 1
    spalte(7) = 1
    spalte(8) = 6
    
    'Tabelle generieren
    ActiveDocument.Tables.Add Range:=Selection.Range, NumRows:=11, NumColumns:= _
        8, DefaultTableBehavior:=wdWord9TableBehavior, AutoFitBehavior:= _
        wdAutoFitFixed
    With Selection.Tables(1)
        .Style = "Tabellenraster"
        .ApplyStyleHeadingRows = True
        .ApplyStyleLastRow = False
        .ApplyStyleFirstColumn = True
        .ApplyStyleLastColumn = False
        .ApplyStyleRowBands = True
        .ApplyStyleColumnBands = False
        For temp = 1 To 8 'Spaltenbreite anpassen
            .Columns(temp).PreferredWidthType = wdPreferredWidthPoints
            .Columns(temp).PreferredWidth = CentimetersToPoints(spalte(temp))
        Next temp
        
        'Zellen verbinden
        Set rng = .Cell(1, 5).Range
        rng.End = .Cell(1, 8).Range.End
        rng.Cells.Merge
        Set rng = .Cell(3, 8).Range
        rng.End = .Cell(5, 8).Range.End
        rng.Cells.Merge
        Set rng = .Cell(7, 8).Range
        rng.End = .Cell(11, 8).Range.End
        rng.Cells.Merge
        Set rng = .Cell(6, 5).Range
        rng.End = .Cell(11, 7).Range.End
        rng.Cells.Merge
        
    End With
    
End Sub