Thema Datum  Von Nutzer Rating
Antwort
20.07.2015 18:40:36 Florian S.
NotSolved
Blau Speichern unter Pfard ordner selber Wählen
 20.07.2015 22:02:03 Gast11098
Solved
21.07.2015 08:06:22 Florian S.
NotSolved
21.07.2015 17:39:38 Gast11098
NotSolved

Ansicht des Beitrags:
Von:
Gast11098		 Datum:
20.07.2015 22:02:03		 Views:
1494		 Rating:
     
Antwort:
 Nein
Thema:
Speichern unter Pfard ordner selber Wählen

Lass es einfach vom Nutzer auswählen:

?
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
Option Explicit 'Variablendeklaration erzwingen
 
Sub PDF()
'
' PDF Makro
'
 
'
  Const C_ROOT = "C:\Users\Benutzer\Desktop\Ergebnisse\"
   
  On Error GoTo ErrHandler
   
  Dim wks As Excel.Worksheet
  Dim strFilename As String
  Dim vntVisiblePrev As Variant
   
  Set wks = Worksheets("Auswertung PDF")
   
  With Application.FileDialog(msoFileDialogFolderPicker)
     
    .Title = "Speicherort für PDF-Datei auswählen ..."
     
    .InitialView = msoFileDialogViewList
    .InitialFileName = C_ROOT
     
    Call .Show
     
    If .SelectedItems.Count > 0 Then
       
      'Hat der Nutzer hat den Pfad verlassen?
      If 0 <> StrComp(Left$(.SelectedItems(1), Len(C_ROOT)), C_ROOT, vbTextCompare) Then
        Stop
        '<reagiere irgendwie darauf>
        Exit Sub
      End If
       
      'der vom Nutzer ausgewählte Pfad
      strFilename = .SelectedItems(1) & "\"
       
      'Achtung:
      ' Hier wird nur geprüft ob die Zelle einen Inhalt hat.
      ' Es wird nicht geprüft ob er auch gültig ist!
      If Trim$(wks.Range("B5")) = "" Then
        Call MsgBox("In '" & wks.Name & "!B5' wurde kein Dateiname festgelegt.", _
                    vbExclamation)
        Exit Sub
      End If
       
      'den Pfad um den Dateinamen ergänzen
      strFilename = strFilename & Trim$(wks.Range("B5").Text) & ".pdf"
       
      'Bem.:
      ' Zum Exportieren muss das Blatt sichtbar sein
       
      vntVisiblePrev = wks.Visible '< aktuelle Einstellung merken
      wks.Visible = xlSheetVisible '< Blatt sichtbar machen
       
      Call wks.ExportAsFixedFormat( _
              Type:=xlTypePDF, _
              Filename:=strFilename, _
              Quality:=xlQualityStandard, _
              IncludeDocProperties:=True, _
              IgnorePrintAreas:=False, _
              OpenAfterPublish:=True)
       
      wks.Visible = vntVisiblePrev '< alte Einstellung wiederherstellen
       
    End If
     
  End With
   
  Exit Sub
ErrHandler:
  Call MsgBox(Err.Description, vbCritical, "Fehler " & Err.Number)
End Sub

Gruß

Ihre Antwort
  • Bitte beschreiben Sie Ihr Problem möglichst ausführlich. (Wichtige Info z.B.: Office Version, Betriebssystem, Wo genau kommen Sie nicht weiter)
  • Bitte helfen Sie ebenfalls wenn Ihnen geholfen werden konnte und markieren Sie Ihre Anfrage als erledigt (Klick auf Häckchen)
  • Bei Crossposting, entsprechende Links auf andere Forenbeiträge beifügen / nachtragen
  • Codeschnipsel am besten über den Code-Button im Text-Editor einfügen
  • Die Angabe der Emailadresse ist freiwillig und wird nur verwendet, um Sie bei Antworten auf Ihren Beitrag zu benachrichtigen
Thema: Name: Email:
WYSIWYG-Editor, ctl00_Content_editor1



  • Bitte beschreiben Sie Ihr Problem möglichst ausführlich. (Wichtige Info z.B.: Office Version, Betriebssystem, Wo genau kommen Sie nicht weiter)
  • Bitte helfen Sie ebenfalls wenn Ihnen geholfen werden konnte und markieren Sie Ihre Anfrage als erledigt (Klick auf Häckchen)
  • Bei Crossposting, entsprechende Links auf andere Forenbeiträge beifügen / nachtragen
  • Codeschnipsel am besten über den Code-Button im Text-Editor einfügen
  • Die Angabe der Emailadresse ist freiwillig und wird nur verwendet, um Sie bei Antworten auf Ihren Beitrag zu benachrichtigen

Thema Datum  Von Nutzer Rating
Antwort
20.07.2015 18:40:36 Florian S.
NotSolved
Blau Speichern unter Pfard ordner selber Wählen
 20.07.2015 22:02:03 Gast11098
Solved
21.07.2015 08:06:22 Florian S.
NotSolved
21.07.2015 17:39:38 Gast11098
NotSolved