Du könntest es damit versuchen:

Option Explicit

Private Declare Function IsClipboardFormatAvailable Lib "user32" (ByVal wFormat As Long) As Long
Private Declare Function OpenClipboard Lib "user32" (ByVal hwnd As Long) As Long
Private Declare Function CloseClipboard Lib "user32" () As Long
Private Declare Function GetClipboardData Lib "user32" (ByVal wFormat As Long) As Long
Private Declare Function lstrlenA Lib "kernel32" (ByVal lpString As Any) As Long
Private Declare Function lstrcpyA Lib "kernel32" (ByVal lpString1 As Any, ByVal lpString2 As Any) As Long
Private Declare Function GlobalLock Lib "kernel32" (ByVal hMem As Long) As Long
Private Declare Function GlobalUnlock Lib "kernel32" (ByVal hMem As Long) As Long

Public Enum ClipboardFormats
  CF_TEXT = &H1&
End Enum


Public Sub Test()
  
  Dim strClipText As String
  Dim hClipText As Long
  Dim pClipText As Long
  
  'Text in der Zwischenablage vorhanden?
  If IsClipboardFormatAvailable(CF_TEXT) Then
    
    Call OpenClipboard(0)
    
    'Verweis auf den Text in der Zwischenablage holen
    hClipText = GetClipboardData(CF_TEXT)
    
    pClipText = GlobalLock(hClipText)
    'Speicher für den Texts reservieren
    strClipText = Space$(lstrlenA(pClipText))
    'Text aus Zwischenablage lesen / kopieren
    Call lstrcpyA(strClipText, pClipText)
    Call GlobalUnlock(hClipText)
    
    Call CloseClipboard
    
  End If
  
  If strClipText <> "" Then
    'Hinweis: Wenn der Text zu lang ist, passt er nicht mehr in das Fenster
    '         und wird nicht vollständig angezeigt.
    MsgBox strClipText, vbInformation, "Zwischenablage"
'    Range("A1").Value = strClipText
  Else
    MsgBox "Zwischenablage ist leer / enthält keine verwendbare Daten.", vbInformation, "Zwischenablage"
  End If
  
End Sub

Beachte bitte die Kommentare.