Das kommt darauf an... wenn es sich um ein wiederholendes Muster handelt, dann kann man das in einer Schleife durchführen.

anhand des vorhin zuerst genannten Beispiels z.B. so:

'#############################################
'### Ort: DieseArbeitsmappe
Option Explicit

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
  
  'einige wichtige Konstanten
  ' (bei Bedarf ändern)
  Const C_SPALTE_START  As Long = 12
  Const C_SPALTE_ENDE   As Long = 13
  Const C_ZEILE_START   As Long = 18
  Const C_ZEILEN_ANZAHL As Long = 28
  
  'Bem.: Mappen können nicht nur Arbeitsblätter enthalten...
  '   >> Es geht hier daher nur weiter, wenn aktuell eine
  '   >> Arbeitsmappe betrachtet wird.
  If Not TypeOf Sh Is Excel.Worksheet _
    Then Exit Sub
  
  '--------------
  Dim lngZeile  As Long
  Dim lngSpalte As Long
  Dim lngVon    As Long
  Dim lngBis    As Long
   
  With Sh
    
    'Zeilen-Begrenzungen setzen (= Startzustand)
    lngVon = C_ZEILE_START
    lngBis = lngVon + C_ZEILEN_ANZAHL
    
    For lngSpalte = C_SPALTE_START To C_SPALTE_ENDE
      
      'hier wird nur zur Veranschaulichung mal was ausgeben:
      ' (kann später entfernt / auskommentiert werden)
      MsgBox .Name & ":" & vbNewLine & _
             " # Zeile " & lngVon & " bis " & lngBis & vbNewLine & _
             " # Spalte " & .Columns(lngSpalte).Column
      
      'das kennen wir schon vor vorher
      For lngZeile = lngVon To lngBis
        .Rows(lngZeile).Hidden = (.Cells(lngZeile, lngSpalte).Value = 0)
      Next lngZeile
      
      'für den nächsten Durchlauf die neuen Zeilen-Begrenzungen berechnen
      lngVon = lngBis + 1
      lngBis = lngVon + C_ZEILEN_ANZAHL
      
    Next lngSpalte
     
  End With
   
End Sub