.... Das lief jetzt Kacke, der Code war noch nicht fertig und ich habe ausversehen TAB und dann Enter gedrückt und damit den letzten Post abgeschickt. Hier schreibe ich also den vorherigen Post fertig:

Sub Mail_luecken()
'Beispiel Lückentext
Dim oApp As Object
dim strBody as string
dim Zeile as long
 
   Zeile = 2   'die Daten werden aus Zeile 2 genommen, das muss natürlich angepasst werden
 
 
   'Text für E-Mail zusammen bauen:
   strBody = "Hallo Lücke1," & vbcrlf &  vbcrlf & "das ist der Inhalt der Zelle D: Lücke2" & vbcrlf & _
             "und das der Inhalt der Zelle E: Lücke3." & vbcrlf &  vbcrlf & _
             "Die Daten stammen alle aus Zeile Lücke4." & vbcrlf &  vbcrlf & _
             "Viele Grüße," & vbcrlf & "Lücke5"
 
   strBody = replace(strBody, "Lücke1", cells(Zeile, 1).value)  'ersetze Lücke1 durch Inhalt aus Spalte A
   strBody = replace(strBody, "Lücke2", cells(Zeile, 4).value)
   strBody = replace(strBody, "Lücke3", cells(Zeile, 5).value)
   strBody = replace(strBody, "Lücke4", Zeile)
   strBody = replace(strBody, "Lücke5", cells(Zeile, 6).value)

 
   Set oApp = CreateObject("OUTLOOK.Application")
   With oApp.CreateItem(0)    'neue E-Mail ohne Vorlage
 
      .To = cells(Zeile, 1).value
      .Bcc = "bcc@example.com"
       
      .Subject = cells(Zeile, 2).value & " " & cells(Zeile, 3).value
      .Body = strBody
 
      .Display    'Anzeigen
      '.Send       'Abschicken
   End With
    
End Sub

Die Funktion replace() ersetzt eine Zeichenkette durch eine andere. Zum Beispiel:

sub beispiel_replace()
   msgbox replace("Hallo Peter", "Peter", "Hans")
end sub

Ich habe das hier einfach so runtergeschrieben und hoffe, dass ich keinen Tippfehler oder ähnliches gemacht habe. Ich konnte es nicht testen und wünsche dir viel Erfolg!

Viele Grüße