Hattu OLEObjects - activeX Controlls am Tabellenblatt, dann für deine Beschreibung

Private Sub CheckBox12_Click()
Dim oOle As Excel.OLEObject
Dim oRow As Long

oRow = CheckBox12.TopLeftCell.Row
With ActiveSheet
   For Each oOle In .OLEObjects
    If TypeName(oOle.Object) = "CheckBox" Then
      If oOle.TopLeftCell.Row = oRow Then
         If oOle.Name <> "CheckBox12" Then
            oOle.Object.Value = CheckBox12.Object.Value
         End If
      End If
    End If
   Next oOle
End With
End Sub

Eleganter geht die Geschichte, wenn du einen eigene Klasse mit dem Change-Ereignis für alle Checkboxen auf dem Arbeitsblatt verwendest

Code für die Klasse (als clsChkBoxes benennen)

Option Explicit

Public WithEvents Cbox As MSForms.CheckBox
 
Public Property Set Reference(c As MSForms.CheckBox)
   Set Cbox = c
End Property
 
Private Sub Cbox_change()

Dim oOle As Excel.OLEObject
Dim oRow As Long
With ActiveSheet
   For Each oOle In .OLEObjects
      If oOle.Name = Cbox.Name Then Exit For
   Next oOle
   oRow = oOle.TopLeftCell.Row
   For Each oOle In .OLEObjects
      If oOle.TopLeftCell.Row = oRow Then oOle.Object.Value = Cbox.Value
   Next oOle
End With

End Sub

Die Klasse baust du beim Öffnen der Arbeitsmappe auf - z.B. für Tabelle1

Option Explicit

Dim myCollection As Collection
 
Private Sub Workbook_Open()

Dim oOle As Excel.OLEObject
Dim oChkBoxes As New clsChkBoxes
     
   Set myCollection = New Collection
   For Each oOle In Sheets("Tabelle1").OLEObjects
      If TypeName(oOle.Object) = "CheckBox" Then
         Set oChkBoxes = New clsChkBoxes
         Set oChkBoxes.Reference = oOle.Object
         myCollection.Add oChkBoxes
      End If
   Next oOle
     
End Sub